날짜와 시간함수

1. CDate : Date 하위 형식의 Variant로 변환된 식을 반환
- 구문 : CDate(date)
- 설명 : date 인수는 유효한 날짜식, 변환값은 컴퓨터의 날짜/시간 설정에 따르며 짧은 날짜 표기법으로 출력

<%
CurDate = "2009/1/7 23:24"
Response.Write CDate(CurDate) & " "
CurDate = "2009년1월7일 23:24"
Response.Write CDate(CurDate) & " "
CurDate = "2009 1 7 23:24"
Response.Write CDate(CurDate) & " "
%>

2. Date : 현재 시스템의 날짜를 반환
- 구문 : Date

<%
Response.Write Date
%>

3. DateAdd : 지정된 날짜에 시간을 추가하거나 뺀 새로운 날짜를 반환
    - 구문 : DateAdd(interval, number, date)
    - 설명 : interval : 연산기준 [yyyy:년, q:분기, m:월, y,d:일(차이점을 잘 모르겠음), w:요일, ww:주, h:시, n:분, s:초]
               number : 간격 수 or 수식. 수식에서 양수는 미래, 음수는 과거
               date : 기준일자

<%
CurDate = Now()
Response.Write CurDate & " "
Response.Write DateAdd("yyyy", 3, CurDate) & " "
Response.Write DateAdd("q", 3, CurDate) & " "
Response.Write DateAdd("m", 3, CurDate) & " "
Response.Write DateAdd("y", 465, CurDate) & " "
Response.Write DateAdd("d", 465, CurDate) & " "
Response.Write DateAdd("w", 465, CurDate) & " "
Response.Write DateAdd("ww", 3, CurDate) & " "
Response.Write DateAdd("h", 3, CurDate) & " "
Response.Write DateAdd("n", 3, CurDate) & " "
Response.Write DateAdd("s", 3, CurDate)
%>

4. DateDiff : 주어지는 두 날짜의 간격을 반환
    - 구문 : DateDiff(interval, date1, date2 [,firstdayofweek[, firstweekofyear]])
    - 설명 : interval : 연산기준 [yyyy:년, q:분기, m:월, y,d:일(차이점을 잘 모르겠음), w:요일, ww:주, h:시, n:분, s:초]
               date1, date2 : 간격을 계산할 두 날짜
               firstdayofweek : 요일을 지정하는 상수(기본값은 1) [1:일, 2:월, 3:화, 4:수, 5:목, 6:금, 7:토]
               firstweekofyear : 연도를 기준으로 한 첫째 주를 지정하는 상수(기본값은 1)
                                    [1:1월 1일을 포함하는 주, 2:새해의 처음 4일을 포함하는 주, 3:새해의 처음 한 주일(7일)을 포함하는 주에서 시작]

<%
CurDate = Now()
CurDate_3 = DateAdd("d", 361, CurDate)

Response.Write DateDiff("yyyy", CurDate, CurDate_3) & " "
Response.Write DateDiff("q", CurDate, CurDate_3) & " "
Response.Write DateDiff("m", CurDate, CurDate_3) & " "
Response.Write DateDiff("y", CurDate, CurDate_3) & " "
Response.Write DateDiff("d", CurDate, CurDate_3) & " "
Response.Write DateDiff("w", CurDate, CurDate_3) & " "
Response.Write DateDiff("ww", CurDate, CurDate_3) & " "
Response.Write DateDiff("h", CurDate, CurDate_3) & " "
Response.Write DateDiff("n", CurDate, CurDate_3) & " "
Response.Write DateDiff("s", CurDate, CurDate_3)
%>

5. DatePart : 주어진 날짜의 지정된 부분을 반환
    - 구문 : DatePart(interval, date[, firstdayofweek[, firstweekofyear]])
    - 설명 : interval : 반환할 시간 간격 기준 [yyyy:년, q:분기, m:월, y,d:일(차이점을 잘 모르겠음), w:요일, ww:주, h:시, n:분, s:초]
               date : 계산할 날짜 or 날짜식
               firstdayofweek : 요일을 지정하는 상수(기본값은 1) [1:일, 2:월, 3:화, 4:수, 5:목, 6:금, 7:토]
               firstweekofyear : 연도를 기준으로 한 첫째 주를 지정하는 상수(기본값은 1)
                                    [1:1월 1일을 포함하는 주, 2:새해의 처음 4일을 포함하는 주, 3:새해의 처음 한 주일(7일)을 포함하는 주에서 시작]

<%
CurDate = Now()

Response.Write DatePart("yyyy", CurDate) & " "
Response.Write DatePart("q", CurDate) & " "
Response.Write DatePart("m", CurDate) & " "
Response.Write DatePart("y", CurDate) & " "
Response.Write DatePart("d", CurDate) & " "
Response.Write DatePart("w", CurDate) & " "
Response.Write DatePart("ww", CurDate) & " "
Response.Write DatePart("h", CurDate) & " "
Response.Write DatePart("n", CurDate) & " "
Response.Write DatePart("s", CurDate)
%>

6. DateSerial : 지정된 년, 월, 일의 Date 하위 형식인 Variant를 반환, 즉 임의의 숫자를 입력받아 날짜 형식으로 반환하는 함수
    - 구문 : DateSerial(year, month, day)
    - 설명 : year : 모든수식 [음수:2000 - 음수, 0:2000, 1~29:2001~2029, 30~99:1930~1999, 100~9999:100~9999]
               month : 모든 수식 [음수:year(1월) - 음수 - 1, 0:year(1월) - 1, 양수:year + 양수]
               day : 모든 수식 [음수:year(1월1일) - 음수 - 1, 0:year(1월1일) - 1, 양수:year + 양수]

<%
Response.Write DateSerial(2007 + 2, 10 + 9, 28 + 20)
%>

7. DateValue : Date 하위 형식의 Variant를 반환, CDate와의 차이점은 CDate는 시간까지 반환, DateValue는 날짜만 반환
- 구문 : DateValue(date)

<%
CurDate = "2009/1/7 23:24"
Response.Write DateValue(CurDate) & " "
CurDate = "2009년1월7일 23:24"
Response.Write DateValue(CurDate) & " "
CurDate = "2009 1 7 23:24"
Response.Write DateValue(CurDate) & " "
%>

8. Day : 날짜를 나타내는 1에서 31까지의 정수를 반환
- 구문 : Day(date)
- 설명 : date 인수는 날짜를 표현하는 식, date 인수에 Null이 있으면 Null을 반환

<%
CurDate = Now()

Response.Write Day(CurDate)
%>

9. Hour : 하루의 시간을 나타내는 0에서 23까지의 정수를 반환
- 구문 : Hour(time)
- 설명 : time 인수는 시간을 나타내는 식, time이 Null이면 Null을 반환

<%
CurDate = Now()

Response.Write Hour(CurDate)
%>

10. IsDate : 날짜형으로 변환될 수 있는지 여부를 나타내는 부울 값을 반환
- 구문 : IsDate(expression)
- 설명 : 날짜이거나 유효한 날짜로 변환될 수 있는 경우 True, 그렇지 않을 경우 False를 반환

<%
CurDate = Now()

Response.Write IsDate(CurDate) & " "
Response.Write IsDate("가나다") & " "
%>

11. Minute : 시간의 분을 나타내는 0에서 59까지의 정수를 반환
- 구문 : Minute(time)
- 설명 : time 인수는 시간을 나타내는 식, time에 Null이 있으면 Null을 반환

<%
CurDate = Now()

Response.Write Minute(CurDate)
%>

12. Month : 년의 월을 나타내는 1에서 12까지의 정수를 반환
- 구문 : Month(date)
- 설명 : date 인수는 날짜를 나타내는 식. date에 Null이 있으면 Null을 반환

<%
CurDate = Now()

Response.Write Month(CurDate)
%>

13. MonthName : 지정한 월을 나타내는 문자열을 반환
    - 구문 : MonthName(month[, abbreviate])
    - 설명 : month : 월을 나타내는 숫자(1~12사이)
               abbreviate : 월 이름을 약어 형태로 표시할지 여부를 나타내는 부울 값. 생략하면 기본값인 False

<%
CurDate = Now()

Response.Write MonthName(Month(CurDate), True) & " "
Response.Write MonthName(Month(CurDate), False)
%>

14. Now : 컴퓨터의 시스템 날짜와 시간을 반환
- 구문 : Now 또는 Now()

<%
Response.Write Now()
%>

15. Second : 분의 초를 나타내는 0에서 59까지의 정수를 반환
- 구문 : Second(time)
- 설명 : time 인수는 시간을 나타내는 식. time 인수에 Null이 있으면 Null을 반환

<%
CurDate = Now()

Response.Write Second(CurDate)
%>

16. Time : 현재 시스템 시간을 나타내는 Date 하위 형식의 Variant를 반환
- 구문 : Time 또는 Time()

<%
Response.Write Time()
%>

17. Timer : 자정 이후 경과한 초 수를 나타내는 Single 값을 반환
- 구문 : Timer 또는 Timer()
- 설명 : 구문의 실행시간을 측정하는데 활용가능

<%
StartTime = Timer()
' 수행구문 (본 예제에서는 아무 작업이 없는 For문을 활용)
For i = 0 To 1000000
Next

EndTime = Timer()
Response.Write " " & EndTime - StartTime
%>

18. TimeSerial : 지정한 시, 분, 초의 Date 하위 형식인 Variant를 반환
    - 구문 : TimeSerial(hour, minute, second)
    - 설명 : time : 0(오전 12:00)에서 23(오후 11:00) 사이의 수 또는 수식, 범위를 벗어나면 날짜와 연산을 함
                minute : 0에서 59 사이의 수 또는 수식, 범위를 벗어나면 시간과 연산을 함
                second : 0에서 59 사이의 수 또는 수식, 범위를 벗어나면 분과 연산을 함

<%
Response.Write TimeSerial(22, 35, 24)
%>

19. TimeValue : 시간을 포함하는 Date 하위 형식의 Variant를 반환
- 구문 : TimeValue(time)

<%
CurDate = "2009년1월7일 오후 11:24:45"
Response.Write TimeValue(CurDate) & " "
CurDate = "23:24:45"
Response.Write TimeValue(CurDate) & " "
%>

20. Weekday : 요일을 나타내는 정수를 반환 [1:일, 2:월, 3:화, 4:수, 5:목, 6:금, 7:토]
    - 구문 : Weekday(date, [firstdayofweek])
    - 설명 : date : 날짜를 나타내는 식. date에 Null이 있으면 Null을 반환
               firstdayofweek : 첫째 요일을 지정하는 상수. 생략하면 1(일요일)로 간주

<%
CurDate = Now()
Response.Write Weekday (CurDate)
%>

21. WeekdayName : 지정된 요일을 나타내는 요일명 문자열을 반환
    - 구문 : WeekDayName(weekday[, abbreviate[, firstdayofweek]])
    - 설명 : weekday : 요일을 나타내는 숫자. firstdayofweek 설정에 따라 각 요일의 값이 다르다.
                abbreviate : 요일 이름을 약어로 나타낼지 여부를 나타내는 부울 값. 생략하면 기본값인 False
                firstdayofweek : 첫째 요일을 나타내는 숫자 값 [1:일, 2:월, 3:화, 4:수, 5:목, 6:금, 7:토]

<%
CurDate = Now()
Response.Write WeekdayName(Weekday(CurDate)) & " "
Response.Write WeekdayName(Weekday(CurDate), True) & " "
Response.Write WeekdayName(Weekday(CurDate), True, 3) & " "
%>

22. Year : 연도를 나타내는 정수를 반환
- 구문 : Year(date)

<%
CurDate = Now()
Response.Write Year(CurDate)
%>

크리에이티브 커먼즈 라이선스

이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-동일조건변경허락 3.0 Unported 라이센스에 따라 이용하실 수 있습니다.

진실세상을 꿈꾸며

날짜와 시간함수

티스토리툴바

날짜와 시간함수

'ASP' Related Articles

티스토리툴바